Project Red and Ender IO

How did you use MineTweaker? Discuss your experience here! You can post your MineTweaker-enabled modpack here, too.

Project Red and Ender IO

Postby EmberQuill » Sun Nov 30, 2014 11:50 pm

I don't really like the crafting recipe for Red Alloy Ingots (it seems needlessly expensive in terms of Redstone, while also being cheap in terms of infrastructure required), so this changes Project Red's recipes to use Ender IO's Redstone Alloy instead of its own Red Alloy Ingots.

Since I removed the old recipes using Red Alloy Ingots as an ingredient, I also removed all of the ways to craft the ingots themselves. I couldn't remove the smeltery alloy recipe for Molten Conductive Redmetal, but since you can't get Molten Redstone it's unobtainable anyway. I just wanted to clean up an unnecessary recipe.

: [Select all] [/] [] ()
  1. import minetweaker.item.IItemStack;
  2. import minetweaker.item.IIngredient;
  3. import mods.tconstruct.Casting;
  4. import mods.tconstruct.Smeltery;
  5.  
  6. // Ender IO Redstone Alloy
  7. val redstoneAlloy = <ore:ingotRedstoneAlloy>;
  8.  
  9. // Project Red Items
  10. val redAlloy = <ProjRed|Core:projectred.core.part:10>;
  11. val redIron = <ProjRed|Core:projectred.core.part:40>;
  12. val wireDebugger = <ProjRed|Core:projectred.core.wiredebugger>;
  13. val wire = <ProjRed|Transmission:projectred.transmission.wire>;
  14. var insulatedWires = [<ProjRed|Transmission:projectred.transmission.wire:1>, <ProjRed|Transmission:projectred.transmission.wire:2>, <ProjRed|Transmission:projectred.transmission.wire:3>, <ProjRed|Transmission:projectred.transmission.wire:4>, <ProjRed|Transmission:projectred.transmission.wire:5>, <ProjRed|Transmission:projectred.transmission.wire:6>, <ProjRed|Transmission:projectred.transmission.wire:7>, <ProjRed|Transmission:projectred.transmission.wire:8>, <ProjRed|Transmission:projectred.transmission.wire:9>, <ProjRed|Transmission:projectred.transmission.wire:10>, <ProjRed|Transmission:projectred.transmission.wire:11>, <ProjRed|Transmission:projectred.transmission.wire:12>, <ProjRed|Transmission:projectred.transmission.wire:13>, <ProjRed|Transmission:projectred.transmission.wire:14>, <ProjRed|Transmission:projectred.transmission.wire:15>, <ProjRed|Transmission:projectred.transmission.wire:16>] as IItemStack[];
  15. var wools = [<minecraft:wool>, <minecraft:wool:1>, <minecraft:wool:2>, <minecraft:wool:3>, <minecraft:wool:4>, <minecraft:wool:5>, <minecraft:wool:6>, <minecraft:wool:7>, <minecraft:wool:8>, <minecraft:wool:9>, <minecraft:wool:10>, <minecraft:wool:11>, <minecraft:wool:12>, <minecraft:wool:13>, <minecraft:wool:14>, <minecraft:wool:15>] as IIngredient[];
  16.  
  17. // Remove Red Alloy recipes
  18. furnace.remove(redAlloy);
  19. recipes.remove(redIron);
  20. Smeltery.removeMelting(<ore:dustRedstone>);
  21. Smeltery.removeMelting(<ore:blockRedstone>);
  22. Casting.removeTableRecipe(redAlloy);
  23. //Smeltery.removeAlloy(<fluid:molten conductive redmetal>); -- Doesn't work!
  24. mods.thermalexpansion.Furnace.removeRecipe(redIron);
  25. mods.thermalexpansion.Smelter.removeRecipe(<minecraft:redstone>, <minecraft:iron_ingot>);
  26.  
  27. // Remove recipes using Red Alloy
  28. recipes.remove(wireDebugger);
  29. recipes.remove(wire);
  30. for i, insWire in insulatedWires {
  31.     recipes.removeShaped(insWire);
  32. }
  33.  
  34. // Add new recipes using Redstone Alloy
  35. recipes.addShaped(wire * 12, [[null, redstoneAlloy, null], [null, redstoneAlloy, null], [null, redstoneAlloy, null]]);
  36. recipes.addShaped(wireDebugger, [[redstoneAlloy, null, redstoneAlloy], [<ore:dyeBlack>, <ore:gemEmerald>, <ore:dyeRed>], [<ore:dyeBlack>, <ore:dustGlowstone>, <ore:dyeRed>]]);
  37. for j, insWire in insulatedWires {
  38.     val wool = wools[j];
  39.     recipes.addShaped(insWire * 12, [[wool, redstoneAlloy, wool], [wool, redstoneAlloy, wool], [wool, redstoneAlloy, wool]]);
  40. }
GeSHi © Codebox Plus
EmberQuill
 
Posts: 2
Joined: Sun Nov 30, 2014 7:00 pm

Return to Usage Discussions

Who is online

Users browsing this forum: No registered users and 1 guest

cron